#***********************************************************************************************
#TopTradeTools.com TOP TICK Dual Confirmation DT

#Copyright (c) 2017-2020 TopTradeTools.com. All rights reserved.

#Programmer Contact: Support@TopTradeTools.com

#Versions:
#1.0 - 06/16/20: First version 

#***********************************************************************************************}
declare lower;

input LookbackST = 21;
input LookbackLT = 145;

script LookBackFunc
{
    input src = 0;
    input lb = 10;
    input nb = 10;


    def _value = fold i1 = 0 to nb with h=0 while h<=lb do if h<lb and isnan(GetValue(src, i1)) == no then h+1 else if h==lb then i1+1 else h;

    plot value = _value;
}

DefineGlobalColor("UpColor", Color.GREEN);
DefineGlobalColor("DownColor", Color.RED);
DefineGlobalColor("NeutralColor", Color.WHITE);
DefineGlobalColor("LineColor", Color.CYAN);
DefineGlobalColor("SepColor", Color.CYAN);

def Var1 = if isnaN(close("$TICK")) then double.NaN else close("$TICK") ;
def Var2 = CompoundValue(1, if isNaN(Var1)==no then Var2[1] + Var1 else Var2[1], Var1);

def barNum = Barnumber();
def bar1 = LookBackFunc(var1, LookbackST, barNum) - 1;
def bar2 = LookBackFunc(var2, LookbackLT, barNum) - 1;

def VarST = if Var2 >= Getvalue(Var2,bar1) then 1 else -1;
def VarLT = if Var2 >= Getvalue(Var2,bar2) then 1 else -1;

def VarSum = VarST + VarLT;

plot LongTerm = if isNaN(Var1) then double.NaN else 1;
LongTerm.SetStyle(Curve.POINTS);
LongTerm.SetLineWeight(5);
LongTerm.AssignValueColor(if VarLT==1 then GlobalColor("UpColor") else GlobalColor("DownColor"));

plot ShortTerm = if isNaN(Var1) then double.NaN else 1.5;
ShortTerm.SetStyle(Curve.POINTS);
ShortTerm.SetLineWeight(5);
ShortTerm.AssignValueColor(if VarST==1 then GlobalColor("UpColor") else GlobalColor("DownColor"));


plot Dual = if isNaN(Var1)==no and (VarSum==2 or VarSum==-2) then 2.5 else double.NaN;
Dual.SetStyle(Curve.POINTS);
Dual.SetLineWeight(5);
Dual.AssignValueColor(if VarSum==2 then GlobalColor("UpColor") else GlobalColor("DownColor"));

plot Bottom = 0.5;
Bottom.AssignValueColor(GlobalColor("LineColor"));

plot SeparatedLine = 2;
SeparatedLine.AssignValueColor(GlobalColor("SepColor"));

plot Top = 3;
Top.AssignValueColor(GlobalColor("LineColor"));